最近开发要使 用图表，Delphi里提供了图表开发的控件TChart，可惜帮助里没有DEMO代码，上网搜索了一下，竟然发现文章也少的可怜。没办法，自己丰衣足 食，写代码试用，看帮助，读代码，搞了半天大概弄明白了TChart的使用方式，下面写一下几个常见问题的解决。
1.如何写一个TChart的Hello World？
放一个控件到窗体上，然后写代码加入一个折线数据序列：
var
Series: TLineSeries;
begin
Series := TLineSeries.Create(Chart1);
Series.Add(100, 'aaa', clRed);
Series.Add(200, 'AAA', clGreen);
Chart1.AddSeries(Series);
end;
这样就会生成一个简单的折线图表，要生成其它类型的数据图表，可以添加不同的数据序列（各种图表的序列类型可以参考帮助文档）。
2.如何设置图表的标题？
TChart组件提供了Title属性可以这是图表的标题，包括标题的内容、字体、对齐方式等都可以通过Title属性设置。
最简单的设置方式：
Chart1.Title.Text.Text := '图表的标题';
3.如何修改图表的背景颜色和整个图表的颜色？
TChart是一个窗体控件，可以通过修改Color属性设置图表颜色，这是一种最简单的方式：
Chart1.Color := clWhite;
修改图表部分的背景色可以通过BackColor属性来实现：
Chart1.BackColor := clGreen;
此外，TChart还提供了渐变的背景支持，通过Gradient控制：
Chart1.Gradient.Visible := True;
Chart1.Gradient.Direction := gdFromTopLeft;
Chart1.Gradient.StartColor := clGreen;
Chart1.Gradient.EndColor := clYellow;
4.TChart的3D效果如何控制？
TChart提供了View3D属性，控制是否使用3D效果，View3dWalls属性控制是否显示左侧的3D墙效果
5.如何不显示图表控件生成图表？
很遗憾，TChart是一个Windows窗体控件，必须依附一个窗体或Windows控件才能使用。如果要不显示TChart的话，可以将TChart的Visible属性设为False来使用。下面的例子创建了一个隐藏的TChart来生成图表：
var
Chart: TChart;
S: TChartSeries;
TmpFile: string;
begin
Chart := TChart.Create(nil);
try
Chart.Parent := Application.MainForm;
Chart.Visible := False;
Chart.Title.Text.Text := '测试图表';
S := TBarSeries.Create(Chart);
Chart.AddSeries(S);
S.Title := '嘿嘿';
S.AddXY(1, 56, '一月', clGreen);
S.AddXY(2, 67, '二月', clYellow);
S.AddXY(3, 34, '三月', clBlue);
S.AddXY(4, 78, '四月', clRed);
Chart.View3D := False;
Chart.BackColor := clWhite;
Chart.Gradient.StartColor := clWhite;
Chart.Gradient.EndColor := clWhite;
Chart.Gradient.Visible := True;
TmpFile := Application.ExeName + '.bmp';
Chart.SaveToBitmapFile(TmpFile);
Image1.Picture.LoadFromFile(TmpFile);
finally
Chart.Free;
end;
end;
－－－－－－导出成图片－－－－－－－－－－－－－－－－－－
TChart7前的TChart可以通过类似于Chart1.Export.SaveToJPEGFile的方法把TChart存成需要的图像格式，但到TChart7后TChart就没有Export属性了，要导出图像要用下面的方法。我尽量用代码说明问题，如果细节不够的话，自己可以查询相应的源代码进行学习。
TChart7提供导出BMP、WMF的方法，直接调用即可，例子如下：
Chart1.SaveToBitmapFile('c:\1.bmp');
Chart1.SaveToMetafile('c:\1.wmf');
TChart7导出JPG（JPEG）也比较简单，在本单元中uses TeeJPEG单元，然后执行TeeJPEG中的TeeSaveToJPEG或TeeSaveToJPEGFile。例子如下：
//注意要包含TeeJPEG才可以。
implementation
uses
TeeJPEG;
procedure TForm1.Button2Click(Sender: TObject);
begin
TeeSaveToJPEG(Chart1, 'c:\1.jpg', -1, -1);//后面的两个参数是宽和高，如果用TeeChart的宽、高可以设为-1.
end;
TChart7导出GIF比较复杂一些，还是用代码举例吧。
//注意要包含TeeGIF才可以。
implementation
uses
TeeGIF;
procedure TForm1.Button3Click(Sender: TObject);
var
exp : TGIFExportFormat;
frm : TTeeGIFOptions;
begin
exp := TGIFExportFormat.Create;
exp.Panel := Chart1;
frm := TTeeGIFOptions(exp.Options());
frm.CBReduction.ItemIndex := 3;
exp.SaveToFile('c:\1.gif');
exp.Free;
end;
稍微解释一下，上面的例子对于TChart7的图像导出很有代表意义，其实所有格式的导出到可以用上例的方式，只是把TGIFExportFormat换成需要的格式即可，因为所有的导出都对应一种格式。
上面例子中，生成一个导出的格式类对象，设置此格式要导出的Chart，如果有必要再设定导出的选项。导出选项要特别提醒一下，所有导出格式的导出选项都是通过格式类的Options()函数得到的窗体进行设置的，这点比较奇怪。
GIF导出是必须设定frm.CBReduction.ItemIndex，因为此项缺省为0，导出是会报“Color Table error....”的错误，所以必须设为非零的值，每个值代表什么意思，自己可以查一下。
TChart7导出PCX同导出GIF极其类似，代码示例如下：
//注意要包含TeePCX才可以。
implementation
uses
TeePCX;
procedure TForm1.Button4Click(Sender: TObject);
var
exp : TPCXExportFormat;
begin
exp := TPCXExportFormat.Create;
exp.Panel := Chart1;
exp.SaveToFile('c:\1.pcx');
exp.Free;
end;
TTChart7可以直接导出到HTM，在本单元中uses TeeVMLCanvas单元，然后执行TeeVMLCanvas中的TeeSaveToVMLFile即可。示例如下：
//注意要包含TeeVMLCanvas才可以。
implementation
uses
TeeVMLCanvas;
procedure TForm1.Button5Click(Sender: TObject);
begin
TeeSaveToVMLFile(Chart1, 'c:\1.html');
end;
TTChart7可以很容易导出到PNG，在本单元中uses TeePNG单元，然后执行TeePNG中的TeeSaveToPNG即可。示例如下：
//注意要包含TeePNG才可以。
implementation
uses
TeePNG;
procedure TForm1.Button7Click(Sender: TObject);
begin
TeeSaveToPNG(Chart1, 'c:\1.png');
end;
要注意的是，保存PNG格式需要LPng.dll，所以为了能正常运行上例代码需下载安装LPng.dll。
本文给出了TeeChart7导出图像时的方法，每种方式都给出了代码示例，希望对使用TChart7的图像导出进行汇总。
